{
  inputs,
  osConfig,
  pkgs,
  ...
}:
{
  imports = [
    inputs.lazyvim.homeManagerModules.default
    ../features/starship.nix
    ../features/home-env.nix
  ];

  home = {
    stateVersion = "26.05";
    shellAliases = import ../features/aliases.nix { inherit pkgs; };
    packages = with pkgs; [ ticker ];

    file = {
      ".ticker.yaml".text = ''
        show-summary: true
        show-tags: true
        show-fundamentals: true
        show-separator: true
        show-positions: true
        interval: 5
        currency: USD
        currency-summary-only: false
        watchlist:
          - AAPL
          - GOOG
          - INTC
          - AMD
          - MSFT
          - ^IXIC
          - ^GSPC
          - ^DJI
      '';
    };
  };

  xdg =
    if pkgs.stdenv.hostPlatform.isDarwin then
      { }
    else
      {
        configFile = {
          "systemd/user/plasma-kwallet-pam.service.d/style.conf" = {
            text = ''
              [Service]
              Environment=QT_STYLE_OVERRIDE=Breeze
            '';
          };
          "systemd/user/kde-baloo.service.d/override.conf" = {
            text = ''
              [Unit]
              After=plasma-kwin_wayland.service
            '';
          };
          "qimgv" = {
            source = ./config/qimgv;
            recursive = true;
          };

          "zathura" = {
            source = ./config/zathura;
            recursive = true;
          };
        };

        dataFile = {
          "applications" = {
            source = ./local/share/applications;
            recursive = true;
          };
        };
      };

  programs = {
    bash = {
      enable = true;

      initExtra = ''
        eval "$(jump shell)"
        eval "$(devenv hook bash)"
        clear;fastfetch
      '';
    };

    zsh =
      if pkgs.stdenv.hostPlatform.isDarwin then
        {
          enable = true;
          enableCompletion = true;
          autosuggestion.enable = true;
          syntaxHighlighting.enable = true;

          initContent = ''
            eval "$(jump shell)"
            eval "$(devenv hook zsh)"
            clear;fastfetch
          '';
        }
      else
        { };

    fastfetch = {
      enable = true;

      settings = {
        modules = [
          "title"
          "separator"
          "os"
          "kernel"
          "uptime"
          "host"
          "localip"
          "packages"
          "shell"
          "terminal"
          "wm"
          "cpu"
          "gpu"
          "memory"
          "disk"
          "break"
        ];

        logo = {
          source = if pkgs.stdenv.hostPlatform.isDarwin then "macos" else "nixos2";
        };
      };
    };

    ssh = {
      enable = true;
      enableDefaultConfig = false;

      settings = {
        "*" = {
          IdentityFile = [
            osConfig.sops.secrets."personal_ssh_key_ed25519".path
            osConfig.sops.secrets."work_ssh_key_rsa".path
          ];
        };

        "daguerro.net" = {
          User = "almalinux";
        };

        "panel.daguerro.net" = {
          User = "floturcocantsee";
        };

        "voffice.picerne.com" = {
          User = "pdcadmin";
        };
      };
    };

    lazyvim = {
      enable = true;

      config = {
        # Enable light mode and configure tabstop
        # to two spaces rather than 4.
        options = ''
          vim.o.background = "light"
          vim.opt.tabstop = 2
          vim.opt.shiftwidth = 2
          vim.opt.expandtab = true
        '';
      };

      extras = {
        lang = {
          nix.enable = true;
          python.enable = true;
          rust.enable = true;
          dotnet.enable = true;
        };
      };

      extraPackages = with pkgs; [
        nix
        alejandra
        statix
      ];
    };

    git = {
      enable = true;
      lfs.enable = true;

      signing = {
        key = osConfig.sops.secrets."personal_ssh_key_ed25519.pub".path;
        signByDefault = true;
      };

      settings = {
        init.defaultBranch = "main";
        safe.directory = if pkgs.stdenv.hostPlatform.isDarwin then "/etc/nix-darwin" else "/etc/nixos";

        user = {
          name = "Frank LoTurco";
          email = "floturcocantsee@protonmail.com";
        };

        gpg = {
          format = "ssh";
        };
      };
    };
  };

  fonts = {
    fontconfig = {
      enable = true;
      subpixelRendering = "none";
      hinting = "slight";
    };
  };
}