{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-26.05";
    nixpkgs-unstable.url = "github:NixOS/nixpkgs/nixos-unstable";

    home-manager = {
      url = "github:nix-community/home-manager/release-26.05";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    nix-darwin = {
      url = "github:nix-darwin/nix-darwin/nix-darwin-26.05";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    nix-flatpak.url = "github:gmodena/nix-flatpak/?ref=v0.7.0";
    appimage-manager.url = "github:kem-a/AppManager";

    i915-sriov-dkms.url = "github:strongtz/i915-sriov-dkms";

    lazyvim.url = "github:pfassina/lazyvim-nix/v16.0.0";

    affinity-nix.url = "github:mrshmllow/affinity-nix";

    affinity-thumbnailer-kde = {
      url = "path:./packages/affinity-thumbnailer-kde";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    scopebuddy.url = "github:HikariKnight/ScopeBuddy";
    nix-gaming.url = "github:fufexan/nix-gaming";
    nixpkgs-xr.url = "github:nix-community/nixpkgs-xr";
  };

  outputs =
    inputs@{
      self,
      nixpkgs,
      nixpkgs-xr,
      home-manager,
      nix-darwin,
      nix-flatpak,
      affinity-nix,
      affinity-thumbnailer-kde,
      i915-sriov-dkms,
      ...
    }:
    let
      home-manager-configuration = { home-manager, ... }: {
        home-manager = {
          useGlobalPkgs = true;
          useUserPackages = true;
          extraSpecialArgs = { inherit inputs; };
          users.frank = ./home/frank.nix;
        };
      };
    in
    {
      nixosConfigurations = {
        nero = nixpkgs.lib.nixosSystem {
          specialArgs = { inherit inputs; };

          modules = [
            home-manager.nixosModules.home-manager
            home-manager-configuration

            nixpkgs-xr.nixosModules.nixpkgs-xr
            nix-flatpak.nixosModules.nix-flatpak
            affinity-thumbnailer-kde.nixosModules.default

            ./hosts/nero/hardware.nix
            ./hosts/nero/configuration.nix
          ];
        };

        pdw-frankiel = nixpkgs.lib.nixosSystem {
          specialArgs = { inherit inputs; };

          modules = [
            home-manager.nixosModules.home-manager
            home-manager-configuration

            nix-flatpak.nixosModules.nix-flatpak
            affinity-thumbnailer-kde.nixosModules.default
            i915-sriov-dkms.nixosModules.default

            ./hosts/pdw-frankiel/hardware.nix
            ./hosts/pdw-frankiel/configuration.nix
          ];
        };
      };

      darwinConfigurations = {
        franks-macbook-pro = nix-darwin.lib.darwinSystem {
          specialArgs = {
            inherit inputs;
            inherit self;
          };

          modules = [
            home-manager.darwinModules.home-manager
            home-manager-configuration

            {
              users.users.frank.home = "/Users/frank";
            }

            ./hosts/franks-macbook-pro/configuration.nix
          ];
        };
      };
    };
}