fork: https://github.com/mrshmllow/affinity-nix

packages/wine/default.nix

@@ -0,0 +1,21 @@
+{ inputs, ... }:
+{
+  perSystem =
+    {
+      pkgs,
+      ...
+    }:
+    let
+      wine-packages = pkgs.callPackage ./packages.nix {
+        inherit inputs;
+      };
+    in
+    {
+      packages.wine = wine-packages.wine;
+
+      _module.args = {
+        inherit (wine-packages) wineUnwrapped;
+        inherit wine-packages;
+      };
+    };
+}

packages/wine/packages.nix

@@ -0,0 +1,27 @@
+{
+  stdenv,
+  callPackage,
+  pkgs,
+  inputs,
+  ...
+}:
+let
+  wineUnstable = inputs.nixpkgs.legacyPackages.${stdenv.hostPlatform.system}.wineWow64Packages.full;
+
+  symlink = callPackage ./symlink.nix { };
+
+  wineUnwrapped = symlink {
+    wine = wineUnstable;
+  };
+
+  wrapWithPrefix = callPackage ./wrapWithPrefix.nix {
+    inherit wineUnwrapped;
+  };
+in
+{
+  inherit wineUnwrapped;
+
+  wine = wrapWithPrefix wineUnwrapped "wine";
+  winetricks = wrapWithPrefix pkgs.winetricks "winetricks";
+  wineserver = wrapWithPrefix wineUnwrapped "wineserver";
+}

packages/wine/symlink.nix

@@ -0,0 +1,15 @@
+{ runCommand }:
+{ wine }:
+runCommand "wine-symlink" { inherit wine; } ''
+  mkdir -p $out/bin
+  for f in $wine/bin/*; do
+    cp -L "$f" $out/bin/
+  done
+
+  ln -s "$wine/bin/wine" $out/bin/wine64
+  for dir in include lib share; do
+    ln -s "$wine/$dir" $out
+  done
+
+  patchShebangs $out
+''

packages/wine/wrapWithPrefix.nix

@@ -0,0 +1,21 @@
+{
+  stdenv,
+  lib,
+  pkgs,
+  wineUnwrapped,
+}:
+pkg: pname:
+stdenv.mkDerivation rec {
+  name = "affinity-${pname}";
+  src = ./.;
+  nativeBuildInputs = [ pkgs.makeWrapper ];
+  installPhase = ''
+    makeWrapper ${lib.getExe' pkg pname} $out/bin/${name} \
+      --set LD_LIBRARY_PATH "${wineUnwrapped}/lib:$LD_LIBRARY_PATH" \
+      --set WINESERVER "${lib.getExe' wineUnwrapped "wineserver"}" \
+      --set WINELOADER "${lib.getExe' wineUnwrapped "wine"}" \
+      --set WINEDLLPATH "${wineUnwrapped}/lib/wine" \
+      --set WINE "${lib.getExe' wineUnwrapped "wine"}"
+  '';
+  meta.mainProgram = name;
+}