fork: https://github.com/mrshmllow/affinity-nix

2026-09-01 10:45:21 -04:00
commit ac32649783
51 changed files with 4837 additions and 0 deletions
@@ -0,0 +1,18 @@
+{ inputs, ... }:
+{
+  perSystem =
+    {
+      pkgs,
+      self',
+      ...
+    }:
+    {
+      packages = {
+        affinity-v3 = pkgs.callPackage ./package.nix {
+          inherit inputs;
+        };
+
+        default = self'.packages.affinity-v3;
+      };
+    };
+}
@@ -0,0 +1,30 @@
+{
+  makeDesktopItem,
+  lib,
+  affinity-v3 ? null,
+}:
+{
+  affinity-v3 = makeDesktopItem rec {
+    desktopName = "Affinity";
+    name = "affinity-v3";
+    exec = "${lib.getExe affinity-v3} %U";
+    icon = name;
+    type = "Application";
+    categories = [ "Graphics" ];
+    keywords = [
+      "Graphics"
+      "2DGraphics"
+      "RasterGraphics"
+      "VectorGraphics"
+      "image"
+      "editor"
+      "vector"
+      "drawing"
+    ];
+    mimeTypes = [
+      "application/afphoto"
+      "application/afdesign"
+    ];
+    startupWMClass = "affinity.exe";
+  };
+}
@@ -0,0 +1,20 @@
+{
+  fetchurl,
+  pkgs,
+  lib,
+}:
+rec {
+  icon = fetchurl {
+    url = "https://web.archive.org/web/20260310003857/https://static.canva.com/domain-assets/affinity/static/images/apple-touch-180x180-1.png";
+    sha256 = "sha256-KLT9loFiD2y8uNXNzc27DZ4A73yEs6Ntr4h3WULG5HM=";
+  };
+
+  iconPackage = pkgs.runCommand "affinity-v3-icons" { } ''
+    mkdir -p $out/share/icons/hicolor/256x256/apps
+
+    ${lib.getExe pkgs.imagemagick} \
+        ${icon} \
+        -resize 256x256 \
+        $out/share/icons/hicolor/256x256/apps/affinity-v3.png
+  '';
+}
@@ -0,0 +1,50 @@
+{
+  symlinkJoin,
+  callPackage,
+  inputs,
+  lib,
+  ...
+}:
+let
+  wine-packages = callPackage ../wine/packages.nix {
+    inherit inputs;
+  };
+
+  apl-combined = callPackage ../apl/apl-combined.nix {
+    src = inputs.plugin-loader-src;
+  };
+
+  prefixBase = callPackage ../prefixWithAffinity.nix {
+    inherit inputs wine-packages apl-combined;
+  };
+
+  runner = callPackage ../runner/package.nix {
+    inherit prefixBase inputs wine-packages;
+    registry-patches = (callPackage ../registry-patches.nix { }).combined;
+    name = "v3";
+  };
+
+  desktop = callPackage ./desktopItems.nix {
+    affinity-v3 = runner.package;
+  };
+
+  icons = callPackage ./icons.nix { };
+  icon-package = icons.iconPackage;
+in
+symlinkJoin {
+  name = "Affinity v3";
+  pname = "affinity-v3";
+  paths = [
+    runner.package
+    desktop.affinity-v3
+    icon-package
+  ];
+  meta = {
+    mainProgram = "affinity-v3";
+
+    description = "Affinity v3";
+    license = lib.licenses.unfree;
+    homepage = "https://affinity.serif.com/";
+    platforms = [ "x86_64-linux" ];
+  };
+}